SkinRestorer/neoforge/build.gradle

plugins {
    id 'multiloader-loader'
    id 'idea'
    id 'eclipse'

    id 'net.neoforged.moddev'

    id 'multiloader-publish'
}

neoForge {
    version = neoforge_version
    
    // Automatically enable neoforge AccessTransformers if the file exists
    def at = project(':common').file('src/main/resources/META-INF/accesstransformer.cfg')
    if (at.exists()) {
        minecraft.accessTransformers.file(at)
    }

    parchment {
        minecraftVersion = parchment_minecraft
        mappingsVersion = parchment_version
    }

    runs {
        configureEach {
            ideName = "NeoForge ${it.name.capitalize()} (${project.path})" // Unify the run config names with fabric
        }

        client {
            client()
            gameDirectory = rootProject.file('run/client')
        }

        server {
            server()
            programArgument '--nogui'
            gameDirectory = rootProject.file('run/server')
        }
    }

    mods {
        "${mod_id}" {
            sourceSet sourceSets.main
        }
    }
}

dependencies {
    implementation "net.neoforged:neoforge:${neoforge_version}"

    jarJar(implementation('org.mineskin:java-client')) {
        version {
            strictly "[${mineskin_client_version},)"
            prefer mineskin_client_version
        }
    }

    additionalRuntimeClasspath "org.mineskin:java-client:${mineskin_client_version}"
}