SkinRestorer/neoforge/build.gradle

plugins {
    id 'multiloader-loader'
    id 'idea'
    id 'eclipse'

    id 'net.neoforged.gradle.userdev'

    id 'multiloader-publish'
}

// Automatically enable neoforge AccessTransformers if the file exists
def at = project(':common').file('src/main/resources/META-INF/accesstransformer.cfg')
if (at.exists()) {
    minecraft.accessTransformers.file(at)
}

jarJar.enable()

tasks.named('jar') {
    archiveClassifier = 'thin'
}

tasks.named('jarJar') {
    archiveClassifier = ''
}

jar.finalizedBy('jarJar')

dependencies {
    implementation "net.neoforged:neoforge:${neoforge_version}"

    implementation(jarJar(group: 'org.mineskin', name: 'java-client', version: mineskin_client_version)) {
        jarJar.ranged(it, "[${mineskin_client_version},)")
    }
}

subsystems {
    parchment {
        minecraftVersion = parchment_minecraft
        mappingsVersion = parchment_version
    }
}

runs {
    configureEach {
        modSource project.sourceSets.main
        systemProperty 'neoforge.enabledGameTestNamespaces', project.mod_id
    }

    client {
        workingDirectory = file('../run/client')
    }

    server {
        programArgument '--nogui'
        workingDirectory = file('../run/server')
    }
}