SkinRestorer/fabric/build.gradle

plugins {
    id 'multiloader-loader'

    id 'fabric-loom'

    id 'multiloader-publish'
}

dependencies {
    minecraft "com.mojang:minecraft:${minecraft_version}"
    mappings loom.layered {
        officialMojangMappings()
        parchment("org.parchmentmc.data:parchment-${parchment_minecraft}:${parchment_version}@zip")
    }
    modImplementation "net.fabricmc:fabric-loader:${fabric_loader_version}"

    modCompileOnly "net.fabricmc.fabric-api:fabric-api:${fabric_api_version}"

    include implementation("org.mineskin:java-client:${mineskin_client_version}")
}

loom {
    def aw = project(':common').file("src/main/resources/${mod_id}.accesswidener")
    if (aw.exists()) {
        accessWidenerPath.set(aw)
    }

    mixin {
        defaultRefmapName.set("${mod_id}.refmap.json")
    }

    runs {
        client {
            client()
            setConfigName('Fabric Client')
            ideConfigGenerated(true)
            runDir('../run/client')
        }

        server {
            server()
            setConfigName('Fabric Server')
            ideConfigGenerated(true)
            runDir('../run/server')
        }
    }
}